@echo on
:: Generation XSLT
:: Ce traitement utilise le processeur SAXON
::   qui nécessite la présence de Java.
:: Se positionner a la racine du site :
::   cd C:\www_template\www
:: Commande :
:: Parametres :
:: 1 : nom du fichier XML source sans le chemin dans XML/SRC 
:: 2 : nom du fichier html a generer avec le chemin en format UNIX 
::     ("slash" - tel qu'il se trouve dans l'URL dans le fichier XML).
::     x = tous
:: Exemple :
:: ..\bin\gen template.xml index.html
IF NOT "%2"=="" (SET PAGE_X=%2) ELSE (SET PAGE_X=x)
:: Repertoire des sources
set RSRC=..\SRC
:: Repertoire des transformations XSL
set RXSL=..\XSL
:: Chemin et fichier de configuration
set FCONFIG=../www/design/Config.xml
:: Controle existence du XML
if exist %RSRC%\%1 goto okxml
echo *********************************
echo fichier %RSRC%\%1 inconnu
echo *********************************
pause
goto :EOF
:okxml
:: Transformation
set TRAV=%date%-%time%
:: remplace espace par zero
set TRAV=%TRAV: =0%
echo Fichier xml lu : %RSRC%\%1  Fichier traite : %PAGE_X%  Horodatage : %date%-%time%

java -cp ..\bin\xmlresolver.jar;..\bin\saxon.jar net.sf.saxon.Transform ^
 -s:%RSRC%\%1 -xsl:%RXSL%\dg8.xsl ^
 dateheure=%TRAV% page=%PAGE_X% fxml=%RSRC%\%1 option=test fconfig=%FCONFIG% ^
 | findstr /B ":" > ..\tmp\trace.txt

:: Afficher html cree
:: Transformer slash en backslash/antislash : 
if %PAGE_X%==x goto :EOF
set TRAV=%PAGE_X% 
set TRAV=%TRAV:/=^\% 
if not exist %TRAV% echo *** %TRAV% inconnu !
if not exist %TRAV% pause
if not exist %TRAV% goto :EOF
if exist %TRAV% type %TRAV% | more
pause